home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Amoszine 4
/
Amoszine 4 (Disk 2 of 3).adf
/
Intuition_Procs
/
intui.lha
/
Demo_2.Amos
/
Demo_2.amosSourceCode
Wrap
AMOS Source Code
|
1992-02-26
|
2KB
|
87 lines
' Demo of OpenScreen, CloseScreen, SetAPen, Rectfill
' note that during the demo the drag bar and back/front gadgets may be used
'
Amos To Back
'
Wait 50
'
_OPENSCREEN[0,0,320,200,5,0,1,2,15,0,0,0," AMOS And Intuition "]
'
For N=1 To 200
'
X=Rnd(320-25) : Y=Rnd(200-40)
'
_SETAPEN[_IS,Rnd(31)]
_RECTFILL[_IS,X,Y+15,X+25,Y+40]
'
Next
'
Wait 100
'
_CLOSESCREEN[_IS]
'
Wait 50
'
Amos To Front
'
Edit
'
Procedure _OPENSCREEN[X,Y,W,H,D,F,B,V,S,C,G,M,T$]
Global _IS
T$=T$+Chr$(0)
Reserve As Work 10,32
A=Start(10)
Doke A,X : Add A,2 : Rem -- x_pos:
Doke A,Y : Add A,2 : Rem -- y_pos:
Doke A,W : Add A,2 : Rem -- width:
Doke A,H : Add A,2 : Rem -- height:
Doke A,D : Add A,2 : Rem -- depth:
Poke A,F : Add A,1 : Rem -- detail_pen:
Poke A,B : Add A,1 : Rem -- block_pen:
Doke A,V : Add A,2 : Rem -- view_modes:
Doke A,S : Add A,2 : Rem -- screen_type:
Loke A,C : Add A,4 : Rem -- font:
Loke A,Varptr(T$) : Add A,4 : Rem -- title:
Loke A,G : Add A,4 : Rem -- gadgets:
Loke A,M : Rem -- bitmap:
Areg(0)=Start(10)
_IS=Intcall(-198)
Erase 10
End Proc
Procedure _CLOSESCREEN[_IS]
Areg(0)=_IS : Rem -- Screen Handle In A0
NULL=Intcall(-66)
End Proc
Procedure _RECTFILL[_IS,A,B,C,D]
Areg(1)=_IS+84
Dreg(0)=A
Dreg(1)=B
Dreg(2)=C
Dreg(3)=D
T=Gfxcall(-306)
End Proc
Procedure _SETAPEN[_IS,C]
Areg(1)=_IS+84
Dreg(0)=C
P=Gfxcall(-342)
End Proc